An Example of Writing Your Own Blog Engine (mini-version) Part Three

Private _blogbll As BlogBLL

Public Property BlogAdapter() As BlogBLL
    Get
        If _blogbll Is Nothing Then
            _blogbll = New BlogBLL
        End If

        Return _blogbll
    End Get
    Set(ByVal value As BlogBLL)
        _blogbll = value
    End Set
End Property

''' <summary>
''' Get's most recent blog post.
''' </summary>
''' <remarks></remarks>
Private Sub GetBlogPost()
    Dim blogPostDT As Blog.BlogPostsViewDataTable = BlogAdapter.GetMostRecentBlogPost()

    Try
        GetBlogPost_Helper(blogPostDT)
    Catch ex As Exception
        'If this fails, it means there are no blog posts in database at all
        'Should maybe redirect to a plain / non-blog page
        Exit Sub
    End Try
End Sub

''' <summary>
''' Get's specific blog post.
''' </summary>
''' <param name="BlogID"></param>
''' <remarks></remarks>
Private Sub GetBlogPost(ByVal blogID As Integer)
    Dim blogPostDT As Blog.BlogPostsViewDataTable = BlogAdapter.GetBlogPost(blogID)
    GetBlogPost_Helper(blogPostDT)
End Sub

''' <summary>
''' Get's all blog posts for a given month/year (archived posts)
''' </summary>
''' <param name="month"></param>
''' <param name="year"></param>
''' <remarks></remarks>
Private Sub GetBlogPost(ByVal month As Integer, ByVal year As Integer)
    Dim blogPostDT As Blog.BlogPostsViewDataTable = BlogAdapter.GetBlogPosts(month, year)
    GetBlogPost_Helper(blogPostDT)
End Sub

Private Sub GetBlogPost_Helper(ByVal blogPostDR As Blog.BlogPostsViewDataTable)
    rptMainList.DataSource = blogPostDR
    rptMainList.DataBind()
End Sub

Protected Sub rptBlogPosts_ItemDataBound(ByVal sender As Object, ByVal e As System.Web.UI.WebControls.RepeaterItemEventArgs) Handles rptBlogPosts.ItemDataBound
    Select Case e.Item.ItemType
        Case ListItemType.Item
            rptBlogPosts_Helper(sender, e)
        Case ListItemType.AlternatingItem
            rptBlogPosts_Helper(sender, e)
    End Select
End Sub

Private Sub rptBlogPosts_Helper(ByVal sender As Object, ByVal e As System.Web.UI.WebControls.RepeaterItemEventArgs)
    Dim lnkBlogPost As HyperLink = DirectCast(e.Item.FindControl("lnkBlogPost"), HyperLink)

    Dim title As String = e.Item.DataItem("Title").ToString().Replace(" ", "_").Replace(".", "").Replace(",", "")

    lnkBlogPost.Text = e.Item.DataItem("Title").ToString()
    'lnkBlogPost.NavigateUrl = String.Format("default.aspx?blogid={0}", e.Item.DataItem("BlogID").ToString())
    lnkBlogPost.NavigateUrl = String.Format("{0}-{1}", e.Item.DataItem("BlogID").ToString(), title)
End Sub

Private Sub rptBlogComments_Helper(ByVal sender As Object, ByVal e As System.Web.UI.WebControls.RepeaterItemEventArgs)
    Dim lblDate As Label = DirectCast(e.Item.FindControl("lblDate"), Label)
    Dim lblPoster As Label = DirectCast(e.Item.FindControl("lblPoster"), Label)
    Dim lnkURL As HyperLink = DirectCast(e.Item.FindControl("lnkURL"), HyperLink)
    Dim lblComment As Label = DirectCast(e.Item.FindControl("lblComment"), Label)

    Dim dateCreated As DateTime
    Dim pubDate As String = "Unknown"
    Try
        dateCreated = e.Item.DataItem("PubDate")
        pubDate = dateCreated.ToLongDateString()
    Catch ex As Exception
    End Try
    lblDate.Text = pubDate

    Dim poster As String = e.Item.DataItem("Username").ToString()
    If String.IsNullOrEmpty(poster) = True Then
        poster = "anonymous"
    End If

    lblPoster.Text = poster
    lblComment.Text = e.Item.DataItem("Comment").ToString()

    Dim url As String = e.Item.DataItem("URL").ToString()
    lnkURL.Text = url
    lnkURL.NavigateUrl = url
End Sub

Protected Sub rptBlogComments_ItemDatabound(ByVal sender As Object, ByVal e As System.Web.UI.WebControls.RepeaterItemEventArgs)
    Select Case e.Item.ItemType
        Case ListItemType.Header
            Dim blogID As Integer = hdnTempBlogID.Value
            Dim lblNumberOfComments As Label = DirectCast(e.Item.FindControl("lblNumberOfComments"), Label)

            lblNumberOfComments.Text = BlogAdapter.GetNumberOfBlogComments(blogID).ToString()
        Case ListItemType.Item
            rptBlogComments_Helper(sender, e)
        Case ListItemType.AlternatingItem
            rptBlogComments_Helper(sender, e)
    End Select
End Sub

Protected Sub rptMainList_ItemCommand(ByVal source As Object, ByVal e As System.Web.UI.WebControls.RepeaterCommandEventArgs) Handles rptMainList.ItemCommand
    Select Case e.CommandName
        Case "PostComment"
            Dim hdnBlogID As HiddenField = DirectCast(e.Item.FindControl("hdnBlogID"), HiddenField)
            Dim tbComment As HtmlTextArea = DirectCast(e.Item.FindControl("tbComment"), HtmlTextArea)
            Dim tbName As HtmlInputText = DirectCast(e.Item.FindControl("tbName"), HtmlInputText)
            Dim tbEmail As HtmlInputText = DirectCast(e.Item.FindControl("tbEmail"), HtmlInputText)
            Dim tbURL As HtmlInputText = DirectCast(e.Item.FindControl("tbURL"), HtmlInputText)

            Dim blogID As Integer = hdnBlogID.Value
            Dim comment As String = tbComment.Value
            Dim username As String = tbName.Value
            Dim email As String = tbEmail.Value
            Dim url As String = tbURL.Value

            Try
                BlogAdapter.CreateBlogComment(blogID, comment, username, email, url)
            Catch ex As Exception
                'FIX add error handling here
            End Try

            'Retrieve blog comments
            Dim rptBlogComments As Repeater = DirectCast(e.Item.FindControl("rptBlogComments"), Repeater)

            rptBlogComments.DataSource = BlogAdapter.GetBlogComments(blogID)
            rptBlogComments.DataBind()
    End Select
End Sub

Protected Sub rptMainList_ItemDataBound(ByVal sender As Object, ByVal e As System.Web.UI.WebControls.RepeaterItemEventArgs) Handles rptMainList.ItemDataBound
    hdnTempBlogID.Value = e.Item.DataItem("BlogID")

    'Retrieve blog comments
    Dim rptBlogComments As Repeater = DirectCast(e.Item.FindControl("rptBlogComments"), Repeater)

    rptBlogComments.DataSource = BlogAdapter.GetBlogComments(e.Item.DataItem("BlogID"))
    rptBlogComments.DataBind()
End Sub

Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
    If Page.IsPostBack = False Then
        Dim month As Integer = 0
        Try
            month = Integer.Parse(Request.QueryString("month"))
        Catch ex As Exception
        End Try

        Dim year As Integer = 0
        Try
            year = Integer.Parse(Request.QueryString("year"))
        Catch ex As Exception
        End Try

        Dim blogID As Integer = 0
        Try
            blogID = Integer.Parse(Request.QueryString("blogid"))
        Catch ex As Exception
        End Try

        If month > 0 And year > 0 Then
            GetBlogPost(month, year)
        ElseIf blogID > 0 Then 'Populate requested blog post
            GetBlogPost(blogID)
        Else 'Populate most recent blog post
            GetBlogPost()
        End If
    End If
End Sub